Date: Tue, 16 Jun 2015 14:39:02 +0200 (CEST)
From: Enrico Mioso <mrkiko.rs@gmail.com>
To: Michael Matz <matz@suse.de>
cc: Borislav Petkov <bp@alien8.de>, linux-kernel@vger.kernel.org,
        x86-ml <x86@kernel.org>
Subject: Re: X86 GIT GCC 5 compilation warning
In-Reply-To: <alpine.LSU.2.20.1506161353270.27315@wotan.suse.de>
Message-ID: <alpine.LNX.2.20.1506161436510.2335@localhost.localdomain>
References: <alpine.LNX.2.20.1506141711200.9260@localhost.localdomain> <20150614180724.GB14892@pd.tnic> <alpine.LSU.2.20.1506151254340.27315@wotan.suse.de> <20150615171750.GP4255@pd.tnic> <alpine.LSU.2.20.1506161353270.27315@wotan.suse.de>
MIME-Version: 1.0
Content-Type: text/plain; charset=US-ASCII
Sender: linux-kernel-owner@vger.kernel.org
Content-Length: 2976
Lines: 97

Hi guys.
First of all - thank you for the discussion, and everything.

I am on arch linux, regularly upgraded.
$ as --version
GNU assembler (GNU Binutils) 2.25.0
Copyright (C) 2014 Free Software Foundation, Inc.
This program is free software; you may redistribute it under the terms of
the GNU General Public License version 3 or later.
This program has absolutely no warranty.
This assembler was configured for a target of `i686-pc-linux-gnu'.

I attach you the PKGBUILD file - the brilliant Arch team made the entire system so it's fairly easy to understand it.


Enrico Mioso

# $Id: PKGBUILD 239643 2015-05-21 23:12:04Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>

# toolchain build order: linux-api-headers->glibc->binutils->gcc->binutils->glibc

# build from head of release branch as bug fix releases are rare

pkgname=binutils
pkgver=2.25
pkgrel=5
_commit=69352378
pkgdesc="A set of programs to assemble and manipulate binary and object files"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/binutils/"
license=('GPL')
groups=('base-devel')
depends=('glibc>=2.20' 'zlib')
makedepends=('git')
checkdepends=('dejagnu' 'bc')
conflicts=('binutils-multilib')
replaces=('binutils-multilib')
options=('staticlibs' '!distcc' '!ccache')
install=binutils.install
source=(git://sourceware.org/git/binutils-gdb.git#commit=${_commit}
        binutils-e9c1bdad.patch)
md5sums=('SKIP'
         'eb3aceaab8ed26e06d505f82beb30f8f')

prepare() {
  cd ${srcdir}/binutils-gdb

  # https://sourceware.org/bugzilla/show_bug.cgi?id=16992
  patch -p1 -i ${srcdir}/binutils-e9c1bdad.patch

  # hack! - libiberty configure tests for header files using "$CPP $CPPFLAGS"
  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure

  mkdir ${srcdir}/binutils-build
}

build() {
  cd ${srcdir}/binutils-build

  ${srcdir}/binutils-gdb/configure --prefix=/usr \
    --with-lib-path=/usr/lib:/usr/local/lib \
    --with-bugurl=https://bugs.archlinux.org/ \
    --enable-threads --enable-shared --with-pic \
    --enable-ld=default --enable-gold --enable-plugins \
    --disable-werror --disable-gdb

  # check the host environment and makes sure all the necessary tools are available
  make configure-host

  make tooldir=/usr
}

check() {
  cd ${srcdir}/binutils-build
  
  # unset LDFLAGS as testsuite makes assumptions about which ones are active
  # ignore failures in gold testsuite...
  make -k LDFLAGS="" check || true
}

package() {
  cd ${srcdir}/binutils-build
  make prefix=${pkgdir}/usr tooldir=${pkgdir}/usr install

  # Remove unwanted files
  rm ${pkgdir}/usr/share/man/man1/{dlltool,nlmconv,windres,windmc}*

  # No shared linking to these files outside binutils
  rm ${pkgdir}/usr/lib/lib{bfd,opcodes}.so
}

--
To unsubscribe from this list: send the line "unsubscribe linux-kernel" in
the body of a message to majordomo@vger.kernel.org
More majordomo info at  http://vger.kernel.org/majordomo-info.html
Please read the FAQ at  http://www.tux.org/lkml/