2024-02-15 18:02:54

by Kees Cook

Subject: [PATCH] cocci: Add rules to find str_plural() replacements

Add rules for finding places where str_plural() can be used. This
currently finds:
54 files changed, 62 insertions(+), 61 deletions(-)

Co-developed-by: Michal Wajdeczko <[email protected]>
Signed-off-by: Michal Wajdeczko <[email protected]>
Link: https://lore.kernel.org/all/[email protected]/
Signed-off-by: Kees Cook <[email protected]>
---
Cc: Michal Wajdeczko <[email protected]>
Cc: Jani Nikula <[email protected]>
Cc: Andy Shevchenko <[email protected]>
Cc: Julia Lawall <[email protected]>
Cc: Nicolas Palix <[email protected]>
Cc: [email protected]

Since ()s are deduplicated by Coccinelle I removed the duplicate rules,
wrapped the final rules in ()s to catch those cases, and added a "!= 1"
case.
---
scripts/coccinelle/api/str_plural.cocci | 41 +++++++++++++++++++++++++
1 file changed, 41 insertions(+)
create mode 100644 scripts/coccinelle/api/str_plural.cocci

diff --git a/scripts/coccinelle/api/str_plural.cocci b/scripts/coccinelle/api/str_plural.cocci
new file mode 100644
index 000000000000..c28cb6f7b803
--- /dev/null
+++ b/scripts/coccinelle/api/str_plural.cocci
@@ -0,0 +1,41 @@
+// SPDX-License-Identifier: GPL-2.0-only
+// Find places to use string_choices.h's str_plural() helper.
+//
+// Confidence: Medium
+virtual patch
+virtual context
+virtual report
+
+@depends on patch@
+expression E;
+@@
+(
+- ((E == 1) ? "" : "s")
++ str_plural(E)
+|
+- ((E != 1) ? "s" : "")
++ str_plural(E)
+|
+- ((E > 1) ? "s" : "")
++ str_plural(E)
+)
+
+@r depends on !patch exists@
+expression E;
+position P;
+@@
+(
+* ((E@P == 1) ? "" : "s")
+|
+* ((E@P != 1) ? "s" : "")
+|
+* ((E@P > 1) ? "s" : "")
+)
+
+@script:python depends on report@
+p << r.P;
+e << r.E;
+@@
+
+coccilib.report.print_report(p[0], "opportunity for str_plural(%s)" % e)
+
--
2.34.1

2024-02-15 20:15:55

by Kees Cook

Subject: Re: [PATCH] cocci: Add rules to find str_plural() replacements

On Thu, Feb 15, 2024 at 09:34:01PM +0200, Andy Shevchenko wrote:
> On Thu, Feb 15, 2024 at 09:33:31PM +0200, Andy Shevchenko wrote:
> > On Thu, Feb 15, 2024 at 10:02:00AM -0800, Kees Cook wrote:
> > > Add rules for finding places where str_plural() can be used. This
> > > currently finds:
> > > 54 files changed, 62 insertions(+), 61 deletions(-)
> >
> > Can we extend this to cover string_choices and call the script probably
> > str_choices.cocci ?
>
> (And add it to MAINTAINERS?)

Sure! I'll send a v2.

--
Kees Cook

2024-02-15 20:45:08

by Andy Shevchenko

Subject: Re: [PATCH] cocci: Add rules to find str_plural() replacements

On Thu, Feb 15, 2024 at 10:02:00AM -0800, Kees Cook wrote:
> Add rules for finding places where str_plural() can be used. This
> currently finds:
> 54 files changed, 62 insertions(+), 61 deletions(-)

Can we extend this to cover string_choices and call the script probably
str_choices.cocci ?


--
With Best Regards,
Andy Shevchenko

2024-02-15 22:40:17

by Andy Shevchenko

Subject: Re: [PATCH] cocci: Add rules to find str_plural() replacements

On Thu, Feb 15, 2024 at 09:33:31PM +0200, Andy Shevchenko wrote:
> On Thu, Feb 15, 2024 at 10:02:00AM -0800, Kees Cook wrote:
> > Add rules for finding places where str_plural() can be used. This
> > currently finds:
> > 54 files changed, 62 insertions(+), 61 deletions(-)
>
> Can we extend this to cover string_choices and call the script probably
> str_choices.cocci ?

(And add it to MAINTAINERS?)

--
With Best Regards,
Andy Shevchenko